Humming Via Kitchen

<mx:Script>
<![CDATA[

public var stickies:Array = new Array();


public function create():void
{
    var sticky:Sticky = new Sticky();
    sticky.show();
    stickies.push(sticky);

}//END: create.


public function load():void
{
    // re initialize stickies.
    for (var i:int = 0; i < stickies.length; i++)
    {
        stickies[i].window.close();
        delete stickies[i];
    }

    var request:URLRequest = new URLRequest("http://localhost:5000/stickies.xml");
    request.method = 'GET';
    var loader:URLLoader = new URLLoader();
    loader.addEventListener(Event.COMPLETE, function (evt:Event):void
    {
        var items:XMLList = (new XML(evt.target.data)).items.child('item');
        if (items.length() > 0)
        {
            for each (var item:XML in items)
            {
                var sticky:Sticky = new Sticky();
                sticky.id = item.id;
                sticky.editor.text = item.body;
                sticky.window.x = item.x * Capabilities.screenResolutionX;
                sticky.window.y = item.y * Capabilities.screenResolutionY;
                sticky.window.width = item.width;
                sticky.window.height = item.height;
                sticky.show();
                stickies.push(sticky);
            }
        }
    });
    loader.load(request);

}//END: load.


public function save():void
{
    for each (var sticky:Sticky in stickies)
    {
        var request:URLRequest;
        if (sticky.id > 0)
        {
            request = new URLRequest('http://localhost:5000/stickies/'+sticky.id);
            if (sticky.editor.text.length > 0)
            {
                request.method = 'PUT';
            }
            else
            {
                request.method = 'DELETE';
            }
        }
        else
        {
            if (sticky.editor.text.length > 0)
            {
                request = new URLRequest('http://localhost:5000/stickies');
                request.method = 'POST';
            }
            else
            {
                continue;
            }
        }
        var variables:URLVariables = new URLVariables();
        variables.x = sticky.window.x / Capabilities.screenResolutionX;
        variables.y = sticky.window.y / Capabilities.screenResolutionY;
        variables.width = sticky.window.width;
        variables.height = sticky.window.height;
        variables.body = sticky.editor.text;
        request.data = variables;

        var loader:URLLoader = new URLLoader();
        loader.load(request);

    }

}//END: save.
]]>
</mx:Script>